Using Regular Expression

• Matches With m//
• The // we have used is a shortcut for the m// (pattern match) operator. Like with qw//, can use any pair of delimiters.
• Can use any nonalphanumeric, non-whitespace characters as a delimiter (not necessarily a paired set).
• Choose delimiters that are not part of the pattern.

$_ = "Hi Charles!";
if(m/Charles/) {
    print "/Charles/ matches!\n";
}

if(m(Charles)) {
    print "(Charles) matches!\n";
}

# try also m{Charles}, m[Charles] m<Charles>

if(m#Charles#) {
    print "#Charles# matches!\n";
}

# try also m!Charles! m^Charles^ m,Charles,

$_ = "http://www.math.ucla.edu";
if(m/^http:\/\//) {
    print "matches!\n";
}

if(m(http://)) {
    print "matches!\n";
}

Option Modifiers

• Appended after ending delimiter of a regular expression to change its behavior from the default.
• Ignoring case: /i
• Make the period (.) match newlines also: /s
• The /s modifier makes the period act like the character class [\d\D] (i.e., match any single character). Can combine modifiers

File

abc
Abc
ABC
abC

Program

while(<>) {
    # abc ABC Abc etc
    if(/abc/i) {
        print $_;
    }  
}

What happens if "s" is removed?

$_ = "PIC20A : Java\nPIC40A : Perl\n";
if(/Java.*Perl/s) {
        print "Perl is after Java.";
}  

two modifiers can be put together

$_ = "PIC20A : Java\nPIC40A : Perl\n";
if(/java.*perl/si) {
        print "Perl is after Java.";
} 

The Binding Operator (=~)

• Takes a regular expression on the right hand side and changes the target of the matching operator to the string named on the left hand side.
• The target of =~ can be any expression that yields some scalar string value, e.g., <STDIN>.

print "Do you like Perl? ";
$likes_perl = (<STDIN>=~/\byes\b/i);
if($likes_perl) {
    print "You like Perl.\n";
}

Using Variable Interpolation in Patterns

• Can construct a regular expression from computed strings

$pattern = "hello";
chomp($_ = <STDIN>);
if(/$pattern/) {
    print "matched";
} else {
    print "not match";
}

Match Variables

• Regular expression memories are available after the pattern matching is finished. They are strings, stored in the variables $1, $2, etc.
• Can be used like regular variables.

$_ = "Hello there, neighbor";
if(/\s(\w+),/) { # memory word between space and comma
    print "the word was $1\n"; # the word was there
}

$_ = "Hello there, neighbor";
if(/(\S+) (\S+), (\S+)/) { # memory word between space and comma
    print "words were $1 $2 $3\n"; # words where Hello there neighbor
}

Substitutions

• Use the substitute operator: s///
• Syntax: s/string_to_change/change/;
• Can use the binding operator with s///, as well, to change the target.
• Note: s/// returns a value – true if substitution was successful, false otherwise.
• Global Substitution: use /g
• To replace all possible non-overlapping matches (each new match starts looking past the old one).
• Syntax: s/string_to_change/change/g;

$_ = "PIC20A is a good.";
s/PIC20A/PIC40A/;
print; # PIC40A is good.

$_ = "My credit card number is 1234567812345678";
s/\d{16}/XXXXXXXXXXXXXXXX/;
"My credit card number is XXXXXXXXXXXXXXXX";
print; 

$_ = "He's out bowling with Amy tonight.";
s/with (\w+)/against $1/;
#He's out bowling against Amy tonight.
print;

$_ = "Amy is older than Ben!";
$temp = " is older than ";
s/(\w+)$temp(\w+)/$2$temp$1/;
# Ben is older than Amy!
print;

$_ = "Amy is very smart. Amy is studying in UCLA.";
s/Amy/Ben/;
# Ben is very smart. Amy is studying in UCLA.
print;
print "\n";
$_ = "Amy is very smart. Amy is studying in UCLA.";
s/Amy/Ben/g;
# Ben is very smart. Ben is studying in UCLA.
print;
print "\n";

$str = "Amy is very smart.";
$str =~ s/Amy/Ben/;
# Ben is very smart.
print $str;

split operator

$time="11:20:35";
@array = split /:/, $time;
# or @array = split(/:/, $time);
print "@array"; # 11 20 35

File

if($a == 5) {
  print "$a is equal to 5";
} else {
  print "Hello World\n";
}

while(<>) {
    chomp;
    @array = split(/[^a-zA-Z]+/, $_);
    print "@array\n";
}

if a
print a is equal to
else
print Hello World n